;************************************
; Select, download and play wav and midi files
; (c) XS Interactive palace.xsia.com:9998 by Loss Angeles
; You may use this script if the comments are left intact
; and the credits remain.

ROOM
	ID 133
	NOPAINTING
	NOCYBORGS
	NAME "   Sound Center"
	PICT "morning.gif"
	SPOT
		ID 10
		DONTMOVEHERE
		OUTLINE 6,133  80,133  80,249  6,249
		ENDSPOT
	SPOT
		ID 9
		DONTMOVEHERE
		OUTLINE 28,335  479,335  479,383  28,383
		ENDSPOT
	DOOR
		ID 3
		NAME "Download / Listen"
		DONTMOVEHERE
		DEST 1024
		OUTLINE 187,343  284,343  284,380  187,380
		SCRIPT
ON SELECT{
{
cSound GLOBAL
cSound sound
"Downloading " cSound & ". Wait for the download to complete before attempting another." & localmsg
}
{ "You are on a mac. Just Click on Play to hear  Midi's." localmsg
} DATETIME 0 > IFELSE
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 1
		NAME "Sexy Fun I"
		DONTMOVEHERE
		OUTLINE 15,143  66,143  66,188  15,188
		SCRIPT
; Door 1 list
; (c) XS Interactive
; By G Diller aka Loss Angeles
ON ENTER{
x1 GLOBAL
-1 x1 =
"Script courtesy of palace.xsia.com:9998" localmsg
}
ON SELECT{

x1 GLOBAL
-1 x1 =
{0 ME SETSPOTSTATELOCAL
1 2 SETSPOTSTATELOCAL
"Start of: " ME SPOTNAME & statusmsg}
{1 ME SETSPOTSTATELOCAL
0 2 SETSPOTSTATELOCAL} ME GETSPOTSTATE ifelse
}
ON ALARM {
{
;Put the sound file names in thearray. 
["tramp1.wav"
"Ineedyou.wav"
"ohsure.wav"
"didscrea.wav"
] thearray =
thearray length noarray =
cSound GLOBAL
x1 GLOBAL
thearray x1 get cSound =
cSound cSoundName =
{ 0 x1 =  
cSoundName " (Start)" & cSoundName = } x1 1 <  IF
{  1  x1 -=  
cSoundName " (The End)" & cSoundName = } 1 x1 + noarray >= IF
x1 itoa ") " & cSoundName & statusmsg
} ME GETSPOTSTATE NOT if
}
	ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		NAME "Midi's"
		DONTMOVEHERE
		OUTLINE 15,193  66,193  66,238  15,238
		SCRIPT
; Door 2 list
; (c) XS Interactive
; By G Diller aka Loss Angeles
ON SELECT{

x1 GLOBAL
-1 x1 =
{0 ME SETSPOTSTATELOCAL
1 1 SETSPOTSTATELOCAL
"Start of: " ME SPOTNAME & statusmsg}
{1 ME SETSPOTSTATELOCAL
0 1 SETSPOTSTATELOCAL} ME GETSPOTSTATE ifelse
}
ON ALARM {
{
["m_angie"
"m_blkmg"
"m_bridgeover"
"m_doitagain"
] thearray =
thearray length noarray =
cSound GLOBAL
x1 GLOBAL
thearray x1 get cSound =
cSound cSoundName =
{ 0 x1 =  
cSoundName " (Start)" & cSoundName = } x1 1 <  IF
{  1  x1 -=  
cSoundName " (The End)" & cSoundName = } 1 x1 + noarray >= IF
x1 itoa ") " & cSoundName & statusmsg
} ME GETSPOTSTATE NOT if
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		NAME "Help"
		DONTMOVEHERE
		OUTLINE 407,343  457,343  457,378  407,378
		SCRIPT
ON SELECT{

"Select a Sound Category. Use \"Next\" to skip to the next selection, \"Previous\" to go back. \"Download\" to get the file and \"Play\" to hear it." localmsg
"PC clients download here. Mac's launch a netscape plugin." localmsg
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 5
		NAME "Play Sound"
		DONTMOVEHERE
		OUTLINE 288,342  346,342  346,381  288,381
		SCRIPT
ON SELECT{
cSound GLOBAL
{
")" cSound  & say
}
{
{ cSound midiplay 
}
{ "http://your.web.location/midi/" cSound & ".mid" & NETGOTO 
} DATETIME 0 > IFELSE
}cSound "m_" substr NOT ifelse
"Playing " cSound & statusmsg
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 6
		NAME "Previous"
		DONTMOVEHERE
		OUTLINE 43,342  124,342  124,379  43,379
		SCRIPT
ON ENTER{
1 1 SETSPOTSTATELOCAL
}
;Previous
ON SELECT{
x1 GLOBAL
1 x1 -=
1 1 SETALARM
2 2 SETALARM
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 7
		NAME "Next"
		DONTMOVEHERE
		OUTLINE 129,343  182,343  182,379  129,379
	SCRIPT
;Next
ON SELECT{
x1 GLOBAL
1 x1 +=
1 1 SETALARM
2 2 SETALARM
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 8
		NAME "Stop Midi Play"
		DONTMOVEHERE
		OUTLINE 347,342  405,342  405,380  348,380
		SCRIPT
ON SELECT{

midistop
}
		ENDSCRIPT
		ENDDOOR
	ENDROOM