;************************************
; Sky Scape Link Room
; (c) XS Interactive palace.xsia.com:9998
; by Loss Angeles 4/97
; You may use this script if the comments are left intact
; and the credits remain.

;----------Production version.
;This script has 3 arrays. One for the site names, one for the site prop, and last for the addy.
;Make sure you have a value in each array or you'll have major problems ;-)
;I've left 3 sample addys and props.
;You may optionally use ":Verbose local message" for those sites that have dynamic ips.
ROOM
	ID 102
	NOPAINTING
	NOCYBORGS
	NAME "Link Room"
	PICT "morning.gif"
	SPOT
		ID 1
		OUTLINE 13,264  78,264  78,296  13,296
		SCRIPT
; (c) XS Interactive
; Link Room main function
; By G Diller aka Loss Angeles
ON ENTER{
"@500,10 Script courtesy of Sky Scape (palace.xsia.com:9998)." localmsg
x1 GLOBAL
-1 x1 =
[861777137 861777115 861777152 861777180 861777198 861777210 861777232 861777246 861777256] setprops
1 4 SETSPOTSTATELOCAL
}
ON ALARM{
;Site names go here
["The Hide Out"
"Chatter's Prop Palace"
"Dynamic IP Example"
] aDesc =
aDesc length noarray =
; prop arrays go here
[
[856045814 856045149 856045158 856045185 856045200 856045217 856045225 856045235 856045248]
[860057598 860057597 860057595 860057596 860057594 860057593 860057591 860057592 860057590]
[860057598 860057597 860057595 860057596 860057594 860057593 860057591 860057592 860057590]
] aProp =
; addy's go here
["palace:hideout.sting.org:9998"
"palace:38.233.206.6:9996"
":Visit the web page at blah blah for the current ip addy"
] aAddy =
cAddy GLOBAL
x1 GLOBAL
aAddy x1 get cAddy =
aDesc x1 get cSite =
aProp x1 get setprops
cSite cSiteName =
x1 iCount =
1 iCount +=
{ 0 x1 =  
cSiteName " (Start)" & cSiteName = } x1 1 <  IF
{ 1 x1 -= 
cSiteName " (End)" & cSiteName = } 2 x1 + noarray > IF
iCount itoa ") " & cSiteName & statusmsg
}

	ENDSCRIPT
		ENDSPOT
	DOOR
		ID 2
		NAME "Begin"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 126,355  180,355  180,376  126,376
		SCRIPT
;(c) XS Interactive
; By Diller aka Loss Angeles
;Reset Button
ON SELECT {
"Reset to top" logmsg
x1 GLOBAL
0 x1 =
1 1 setalarm
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 3
		NAME "Previous"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 189,354  248,354  248,377  189,377
		SCRIPT
;(c) XS Interactive
; By Diller aka Loss Angeles
;Previous Site
ON SELECT{
x1 GLOBAL
1 x1 -=
1 1 SETALARM
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		NAME "Next Site"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 258,354  317,354  317,377  258,377
		SCRIPT
;(c) XS Interactive
; By Diller aka Loss Angeles
;Nextsite
ON SELECT{
{
x1 GLOBAL
1 x1 +=
1 1 SETALARM
0 ME SETSPOTSTATELOCAL
{1 ME SETSPOTSTATELOCAL} 240 ALARMEXEC
}
{
"Slow down!" statusmsg
1 ME SETSPOTSTATELOCAL
{ "" STATUSMSG } 220 ALARMEXEC
}ME GETSPOTSTATE ISWIZARD OR ifelse
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 5
		NAME "Goto Site"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 325,353  382,353  382,377  325,377
		SCRIPT
;(c) XS Interactive
; By Diller aka Loss Angeles
;GotoSite
ON SELECT{
cAddy GLOBAL
{ cAddy localmsg
}
{ cAddy netgoto
"Going to  " cAddy &  localmsg
} cAddy "^:" grepstr ifelse
}
		ENDSCRIPT
		ENDDOOR
	ENDROOM