;************************************
; Sky Scape Prop Room
; (c) XS Interactive palace.xsia.com:9998
; by Loss Angeles 8/97
; You may use this script if the comments are left intact
; and the credits remain.

;----------Final release.
ROOM
	ID 127
	NOPAINTING
	NOCYBORGS
	NOGUESTS
	NAME "XS Prop"
	PICT "pgate.gif"
	DOOR
		ID 3
		NAME "Next Room"
		SHOWNAME
		DEST 1042
		OUTLINE 408,357  502,357  488,374  424,374
		ENDDOOR
	DOOR
		ID 1
		NAME "Reset the Loop"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 6,355  90,355  90,377  6,377
		SCRIPT
ON SELECT {
"Resetting Buttons to Start" logmsg
naked
x1 GLOBAL
0 x1 =
}
	ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		NAME "Next Prop"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 171,356  227,356  227,377  171,377
		SCRIPT
;Jump to prop. (c) xsia.com  4/97
;By Loss Angeles
ON ENTER {
"@500,10 Script courtesy of Sky Scape (palace.xsia.com:9998)." localmsg
fDon_it GLOBAL
fStop_it GLOBAL
x1 GLOBAL
0 x1 =
1 ME SETSPOTSTATELOCAL
{
x1 GLOBAL
;Prop id's go here
[" -1341327540 -1341315233 -1341315106 -1341315242 -1341315264 -1341324029" 
" -1341220289 -1341176475 -1341226570 -1341176105 -1341176447 -1341176043 -1341226566" 
" -1341221166 -1341221477 -1341221204 -1341221184 -1341221152 -1341221866" 
" -1341477572 -1341477277 -1341477673 -1341477455 -1341477559 -1341477589" 
" -1342820018 -1342818735 -1342819003 -1342819242 -1342818629 -1342819088 -1342818603" 
] thearray =
noarray GLOBAL
thearray length noarray =
"button1: row " 1 x1 + itoa + "/" + noarray itoa + logmsg
thearray x1 get xpropo =
1 x1 +=
{ 0 x1 =  } 1 x1 + noarray >  IF
"["  xpropo + "] SETPROPS" + xpropo =
0 ME SETSPOTSTATELOCAL
xpropo  STRTOATOM EXEC
{1 ME SETSPOTSTATELOCAL} 240 ALARMEXEC
} fDon_it def
{"Slow down!" statusmsg
{"" STATUSMSG} 220 ALARMEXEC
} fStop_it def
}
ON SELECT{
fDon_it GLOBAL
fStop_it GLOBAL
{fDon_it EXEC
}
{fStop_it EXEC
}ME GETSPOTSTATE ISWIZARD OR ifelse
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		NAME "Jump to Prop"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 235,354  313,354  313,379  235,379
		SCRIPT
;Jump to prop. (c) xsia.com  4/97
ON SELECT{
"Type \"jp <number>\" to jump directly to a prop ID." localmsg
}
ON OUTCHAT{
fDon_it GLOBAL
x1 GLOBAL
noarray GLOBAL
{
100 noarray=
}noarray 0 == if
{
{"$1" grepsub  atoi x1  =
x1--
"Jumped to " 1 x1 + itoa & logmsg
fDon_it EXEC
}
{"The selection is out of range. Total props are " noarray itoa & localmsg
} noarray "$1" grepsub atoi > IFELSE
"" CHATSTR =
}CHATSTR "^jp (-*[0-9].*)" GREPSTR IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 5
		NAME "Back One"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 100,353  163,353  163,380  100,380
		SCRIPT
;(c) xsia.com 4/97
ON SELECT{
fDon_it GLOBAL
x1 GLOBAL
{
-2 x1 + x1 =
fDon_it EXEC
}x1 1 > if
}
		ENDSCRIPT
		ENDDOOR
	ENDROOM