; starburst/circle/spiral Script - uses polar coordinates
; written by jeff schwartz, webdog@webdog.com
; original version january 1997
; converted to iptscrae version 1 sine/cosine function by Foxy, february 2000
; Finally posted by LA to the public April 2001
; Begin Prep

{

MOUSEPOS ymouse = xmouse =

PENBACK

PAINTCLEAR

3 PENSIZE

220 35 RANDOM + 255 RANDOM 255 RANDOM PENCOLOR

0 i =

0 thetafull =

15 thetaadd =

1 numrotations =

60 radius =

;***Begin spiral Only Code***

{ 4 numrotations = } CHATSTR "spiral" == IF

;***End spiral Only Code***

;***Begin starburst Only Code***

{

131 40 RANDOM + thetaadd =

80 radius =

16 numrotations =

2 PENSIZE

} CHATSTR "starburst" == IF

;***End starburst Only Code***

360 numrotations * thetaadd / iterations =

; End Prep

{

thetaadd thetafull +=

thetafull theta360 =

360 theta360 %=

;

;***Begin Circle Only Code***

{

theta360 cosine radius * 1000 / x0 =

theta360 sine radius * 1000 / y0 =

}

CHATSTR "circle" == IF

;***End Circle Only Code***

;***Begin Spiral Only Code***

{

theta360 cosine 80 i + 2 / * 1000 / x0 =

theta360 sine 80 i + 2 / * 1000 / y0 =

}

CHATSTR "spiral" == IF

;***End Spiral Only Code***

;***Begin starburst Only Code***

{

theta360 cosine radius * 1000 / x0 =

theta360 sine radius * 1000 / y0 =

}

CHATSTR "starburst" == IF

;***End starburst Only Code***

;

;Move axis to mouse position

xmouse x0 += ymouse y0 +=

;

;Draw!!!

{xold yold x0 y0 LINE} i IF

x0 xold =

y0 yold =

i++

}

{ i iterations <= } WHILE

} CHATSTR "circle" == CHATSTR "spiral" == OR CHATSTR "starburst" == OR IF

; End starburst/circle/spiral Script